@echo off

:: подразумевается что драйвера, net-snmp и php уже установленны с системой

:: В первой строке меняем текущий диск, во второй - замена на диск и путь из которых запущен командный файл(необходимо при запуске от имени администратора)
 %~d0
 cd /D "%~p0"

:: 1)Переменные
  
 set MainKSRSDir=d:\ksrs-terminal
 set DepKSRSQt=..\Dependencies\Windows\Qt\Qt485
 set TermKSRSUnits=..\Terminal\Modules
 set TermLIRADrv=..\Terminal\Drv\Windows
 set Windows=%SystemRoot%
 set vc90Debug=Microsoft.VC90.DebugCRT
 set dirMain=%cd%
 set LiraDrv32=%SystemRoot%\system32\drivers\ftdibus.sys
 ::set LiraDrv64=%SystemRoot%\syswow64\drivers\ftdibus.sys

:: 2)проверка директории, если нет создаем

 echo "Lira drivers checking.. "
 if exist %LiraDrv32% (echo OK) else (goto no_drv)

 echo "create main directory (%MainKSRSDir%).. "
 if exist %MainKSRSDir% (echo OK) else (md %MainKSRSDir% && echo OK)

 cd /d %MainKSRSDir%
 
 echo stop "krs-terminal-server" service.. 
 krs-terminal-server --stop
 if %errorlevel% == 0 (echo OK) 
 
 echo "stop "snmp-agent" service.."
 snmp-agent --stop
 if %errorlevel% == 0 (echo OK) 

 echo "stopping KARSTerminal.. "
 taskkill /im KARSTerminal.exe
 if %errorlevel% == 0 (echo OK) else (echo process not running)
 
 cd /d %dirMain%
 
:: 3)дополнительные пакеты - qt, microsoft.vc90

echo "copy Qt file.. "
 xcopy %DepKSRSQt% /e/y %MainKSRSDir% /q || xcopy %DepKSRSQt% /e/y %Windows% /q 
 if %errorlevel% == 0 (echo OK) else (echo fail) 
 
 echo "copy %vc90Debug% file.. "
 xcopy %TermKSRSUnits%\%vc90Debug% /e/y %MainKSRSDir%\%vc90Debug%\ /q
 if %errorlevel% == 0 (echo OK) else (echo fail) 

:: 4) копируем в корень Терминала все из папки Terminal

 echo "copy Terminal file.. "
 xcopy %TermKSRSUnits%\Windows /e/y %MainKSRSDir%\ /q
 if %errorlevel% == 0 (echo OK) else (echo fail ) 

 echo "checking configuration file.."
 if exist %MainKSRSDir%\config\KARSTerminal.conf (echo OK) else (xcopy %TermKSRSUnits%\config /e/y %MainKSRSDir%\config\ /q && echo "create configuration file OK")

:: 5)Блок сервисов

 cd /d %MainKSRSDir%
 krs-terminal-server --install

 if %errorlevel% == 0 (echo "krs-terminal-server started")

 snmp-agent --start
 if %errorlevel% == 0 (echo "snmp-agent started")

 start KARSTerminal.exe 
 if %errorlevel% == 0 (echo "KARSTerminal started")

 echo "Setup terminal software completed successfully!"
 echo -------------------------------------------------

goto end

:no_drv
echo "Lira drivers not exist!"
echo "To be continue installation, you must install the drivers!" 
echo -----------------------------------------------------------

:end
pause